Gecko [ georgetownmover.com ]

Name	Size	Permission	Date
codeset.m4	832 B	-rw-r--r--	2015-07-29 20:09
extern-inline.m4	4.24 KB	-rw-r--r--	2015-07-29 20:09
fcntl-o.m4	4.56 KB	-rw-r--r--	2015-07-29 20:09
freetype2.m4	6.2 KB	-rw-r--r--	2015-07-29 19:48
gettext.m4	14.89 KB	-rw-r--r--	2015-07-29 20:09
glibc2.m4	830 B	-rw-r--r--	2015-07-29 20:09
glibc21.m4	907 B	-rw-r--r--	2015-07-29 20:09
iconv.m4	9.05 KB	-rw-r--r--	2015-07-29 20:09
intdiv0.m4	2.35 KB	-rw-r--r--	2015-07-29 20:09
intl.m4	11.84 KB	-rw-r--r--	2015-07-29 20:09
intldir.m4	923 B	-rw-r--r--	2015-07-29 20:09
intlmacosx.m4	2.48 KB	-rw-r--r--	2015-07-29 20:09
intmax.m4	1.1 KB	-rw-r--r--	2015-07-29 20:09
inttypes-pri.m4	1.22 KB	-rw-r--r--	2015-07-29 20:09
inttypes_h.m4	1020 B	-rw-r--r--	2015-07-29 20:09
lcmessage.m4	1.34 KB	-rw-r--r--	2015-07-29 20:09
lib-ld.m4	3.6 KB	-rw-r--r--	2015-07-29 20:09
lib-link.m4	32.28 KB	-rw-r--r--	2015-07-29 20:09
lib-prefix.m4	8.27 KB	-rw-r--r--	2015-07-29 20:09
libmcrypt.m4	8.42 KB	-rw-r--r--	2015-06-25 14:27
libtool.m4	298.56 KB	-rw-r--r--	2015-07-29 19:58
libxml.m4	7.7 KB	-rw-r--r--	2021-03-26 11:36
libxslt.m4	7.93 KB	-rw-r--r--	2019-02-28 16:44
lock.m4	1.43 KB	-rw-r--r--	2015-07-29 20:09
longlong.m4	4.63 KB	-rw-r--r--	2015-07-29 20:09
ltargz.m4	2.51 KB	-rw-r--r--	2015-07-29 19:58
ltdl.m4	29.33 KB	-rw-r--r--	2015-07-29 19:58
ltoptions.m4	14.17 KB	-rw-r--r--	2015-07-29 19:58
ltsugar.m4	4.28 KB	-rw-r--r--	2015-07-29 19:58
ltversion.m4	699 B	-rw-r--r--	2015-07-29 19:58
lt~obsolete.m4	6 KB	-rw-r--r--	2015-07-29 19:58
nls.m4	1.2 KB	-rw-r--r--	2015-07-29 20:09
po.m4	18.53 KB	-rw-r--r--	2015-07-29 20:09
printf-posix.m4	1.54 KB	-rw-r--r--	2015-07-29 20:09
progtest.m4	3.03 KB	-rw-r--r--	2015-07-29 20:09
size_max.m4	2.99 KB	-rw-r--r--	2015-07-29 20:09
stdint_h.m4	995 B	-rw-r--r--	2015-07-29 20:09
threadlib.m4	14.8 KB	-rw-r--r--	2015-07-29 20:09
uintmax_t.m4	1.09 KB	-rw-r--r--	2015-07-29 20:09
visibility.m4	3.27 KB	-rw-r--r--	2015-07-29 20:09
wchar_t.m4	818 B	-rw-r--r--	2015-07-29 20:09
wint_t.m4	1.03 KB	-rw-r--r--	2015-07-29 20:09
xsize.m4	406 B	-rw-r--r--	2015-07-29 20:09

Rename

# size_max.m4 serial 10
dnl Copyright (C) 2003, 2005-2006, 2008-2015 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

dnl From Bruno Haible.

AC_DEFUN([gl_SIZE_MAX],
[
  AC_CHECK_HEADERS([stdint.h])
  dnl First test whether the system already has SIZE_MAX.
  AC_CACHE_CHECK([for SIZE_MAX], [gl_cv_size_max], [
    gl_cv_size_max=
    AC_EGREP_CPP([Found it], [
#include <limits.h>
#if HAVE_STDINT_H
#include <stdint.h>
#endif
#ifdef SIZE_MAX
Found it
#endif
], [gl_cv_size_max=yes])
    if test -z "$gl_cv_size_max"; then
      dnl Define it ourselves. Here we assume that the type 'size_t' is not wider
      dnl than the type 'unsigned long'. Try hard to find a definition that can
      dnl be used in a preprocessor #if, i.e. doesn't contain a cast.
      AC_COMPUTE_INT([size_t_bits_minus_1], [sizeof (size_t) * CHAR_BIT - 1],
        [#include <stddef.h>
#include <limits.h>], [size_t_bits_minus_1=])
      AC_COMPUTE_INT([fits_in_uint], [sizeof (size_t) <= sizeof (unsigned int)],
        [#include <stddef.h>], [fits_in_uint=])
      if test -n "$size_t_bits_minus_1" && test -n "$fits_in_uint"; then
        if test $fits_in_uint = 1; then
          dnl Even though SIZE_MAX fits in an unsigned int, it must be of type
          dnl 'unsigned long' if the type 'size_t' is the same as 'unsigned long'.
          AC_COMPILE_IFELSE(
            [AC_LANG_PROGRAM(
               [[#include <stddef.h>
                 extern size_t foo;
                 extern unsigned long foo;
               ]],
               [[]])],
            [fits_in_uint=0])
        fi
        dnl We cannot use 'expr' to simplify this expression, because 'expr'
        dnl works only with 'long' integers in the host environment, while we
        dnl might be cross-compiling from a 32-bit platform to a 64-bit platform.
        if test $fits_in_uint = 1; then
          gl_cv_size_max="(((1U << $size_t_bits_minus_1) - 1) * 2 + 1)"
        else
          gl_cv_size_max="(((1UL << $size_t_bits_minus_1) - 1) * 2 + 1)"
        fi
      else
        dnl Shouldn't happen, but who knows...
        gl_cv_size_max='((size_t)~(size_t)0)'
      fi
    fi
  ])
  if test "$gl_cv_size_max" != yes; then
    AC_DEFINE_UNQUOTED([SIZE_MAX], [$gl_cv_size_max],
      [Define as the maximum value of type 'size_t', if the system doesn't define it.])
  fi
  dnl Don't redefine SIZE_MAX in config.h if config.h is re-included after
  dnl <stdint.h>. Remember that the #undef in AH_VERBATIM gets replaced with
  dnl #define by AC_DEFINE_UNQUOTED.
  AH_VERBATIM([SIZE_MAX],
[/* Define as the maximum value of type 'size_t', if the system doesn't define
   it. */
#ifndef SIZE_MAX
# undef SIZE_MAX
#endif])
])

dnl Autoconf >= 2.61 has AC_COMPUTE_INT built-in.
dnl Remove this when we can assume autoconf >= 2.61.
m4_ifdef([AC_COMPUTE_INT], [], [
  AC_DEFUN([AC_COMPUTE_INT], [_AC_COMPUTE_INT([$2],[$1],[$3],[$4])])
])