Gecko [ georgetownmover.com ]

Name	Size	Permission	Date
argz.m4	2.56 KB	-rw-r--r--	2026-05-14 17:32
codeset.m4	832 B	-rw-r--r--	2026-05-14 17:36
fcntl-o.m4	4.56 KB	-rw-r--r--	2026-05-14 17:36
freetype2.m4	6.2 KB	-rw-r--r--	2026-05-14 17:34
gettext.m4	14.89 KB	-rw-r--r--	2026-05-14 17:36
glibc2.m4	830 B	-rw-r--r--	2026-05-14 17:36
glibc21.m4	907 B	-rw-r--r--	2026-05-14 17:36
iconv.m4	8.89 KB	-rw-r--r--	2026-05-14 17:36
intdiv0.m4	2.35 KB	-rw-r--r--	2026-05-14 17:36
intl.m4	11.66 KB	-rw-r--r--	2026-05-14 17:36
intldir.m4	923 B	-rw-r--r--	2026-05-14 17:36
intlmacosx.m4	2.48 KB	-rw-r--r--	2026-05-14 17:36
intmax.m4	1.1 KB	-rw-r--r--	2026-05-14 17:36
inttypes-pri.m4	1.22 KB	-rw-r--r--	2026-05-14 17:36
inttypes_h.m4	1020 B	-rw-r--r--	2026-05-14 17:36
lcmessage.m4	1.34 KB	-rw-r--r--	2026-05-14 17:36
lib-ld.m4	3.6 KB	-rw-r--r--	2026-05-14 17:36
lib-link.m4	32.28 KB	-rw-r--r--	2026-05-14 17:36
lib-prefix.m4	8.27 KB	-rw-r--r--	2026-05-14 17:36
libcurl.m4	10.94 KB	-rw-r--r--	2026-05-14 17:33
libmcrypt.m4	8.42 KB	-rw-r--r--	2026-05-14 17:33
libtool.m4	279.64 KB	-rw-r--r--	2026-05-14 17:32
libxml.m4	7.7 KB	-rw-r--r--	2026-05-14 17:28
libxslt.m4	7.93 KB	-rw-r--r--	2026-05-14 17:28
lock.m4	1.24 KB	-rw-r--r--	2026-05-14 17:36
longlong.m4	4.63 KB	-rw-r--r--	2026-05-14 17:36
ltdl.m4	26.42 KB	-rw-r--r--	2026-05-14 17:32
ltoptions.m4	12.06 KB	-rw-r--r--	2026-05-14 17:32
ltsugar.m4	4.27 KB	-rw-r--r--	2026-05-14 17:32
ltversion.m4	690 B	-rw-r--r--	2026-05-14 17:32
lt~obsolete.m4	5.98 KB	-rw-r--r--	2026-05-14 17:32
nls.m4	1.2 KB	-rw-r--r--	2026-05-14 17:36
po.m4	18.5 KB	-rw-r--r--	2026-05-14 17:36
printf-posix.m4	1.54 KB	-rw-r--r--	2026-05-14 17:36
progtest.m4	3.03 KB	-rw-r--r--	2026-05-14 17:36
size_max.m4	2.99 KB	-rw-r--r--	2026-05-14 17:36
stdint_h.m4	995 B	-rw-r--r--	2026-05-14 17:36
threadlib.m4	14.1 KB	-rw-r--r--	2026-05-14 17:36
uintmax_t.m4	1.09 KB	-rw-r--r--	2026-05-14 17:36
visibility.m4	3.27 KB	-rw-r--r--	2026-05-14 17:36
wchar_t.m4	818 B	-rw-r--r--	2026-05-14 17:36
wint_t.m4	1.03 KB	-rw-r--r--	2026-05-14 17:36
xsize.m4	406 B	-rw-r--r--	2026-05-14 17:36

Rename

# intdiv0.m4 serial 6 (gettext-0.18.2)
dnl Copyright (C) 2002, 2007-2008, 2010-2012 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

dnl From Bruno Haible.

AC_DEFUN([gt_INTDIV0],
[
  AC_REQUIRE([AC_PROG_CC])dnl
  AC_REQUIRE([AC_CANONICAL_HOST])dnl

AC_CACHE_CHECK([whether integer division by zero raises SIGFPE],
    gt_cv_int_divbyzero_sigfpe,
    [
      gt_cv_int_divbyzero_sigfpe=
changequote(,)dnl
      case "$host_os" in
        macos* | darwin[6-9]* | darwin[1-9][0-9]*)
          # On Mac OS X 10.2 or newer, just assume the same as when cross-
          # compiling. If we were to perform the real test, 1 Crash Report
          # dialog window would pop up.
          case "$host_cpu" in
            i[34567]86 | x86_64)
              gt_cv_int_divbyzero_sigfpe="guessing yes" ;;
          esac
          ;;
      esac
changequote([,])dnl
      if test -z "$gt_cv_int_divbyzero_sigfpe"; then
        AC_RUN_IFELSE(
          [AC_LANG_SOURCE([[
#include <stdlib.h>
#include <signal.h>

static void
sigfpe_handler (int sig)
{
  /* Exit with code 0 if SIGFPE, with code 1 if any other signal.  */
  exit (sig != SIGFPE);
}

int x = 1;
int y = 0;
int z;
int nan;

int main ()
{
  signal (SIGFPE, sigfpe_handler);
/* IRIX and AIX (when "xlc -qcheck" is used) yield signal SIGTRAP.  */
#if (defined (__sgi) || defined (_AIX)) && defined (SIGTRAP)
  signal (SIGTRAP, sigfpe_handler);
#endif
/* Linux/SPARC yields signal SIGILL.  */
#if defined (__sparc__) && defined (__linux__)
  signal (SIGILL, sigfpe_handler);
#endif

z = x / y;
  nan = y / y;
  exit (2);
}
]])],
          [gt_cv_int_divbyzero_sigfpe=yes],
          [gt_cv_int_divbyzero_sigfpe=no],
          [
            # Guess based on the CPU.
changequote(,)dnl
            case "$host_cpu" in
              alpha* | i[34567]86 | x86_64 | m68k | s390*)
                gt_cv_int_divbyzero_sigfpe="guessing yes";;
              *)
                gt_cv_int_divbyzero_sigfpe="guessing no";;
            esac
changequote([,])dnl
          ])
      fi
    ])
  case "$gt_cv_int_divbyzero_sigfpe" in
    *yes) value=1;;
    *) value=0;;
  esac
  AC_DEFINE_UNQUOTED([INTDIV0_RAISES_SIGFPE], [$value],
    [Define if integer division by zero raises signal SIGFPE.])
])